Dostal se mi do ruky velmi jednoduchý freeware interpret jazyka Basic - cbasPad. V paměti Palmu zabírá pouhých 50 kB (plus MathLib). CbasPad disponuje pouze nejzákladnějšími konstrukcemi jazyka Basic, takže není problém se s ním ve velmi krátké době sblížit a použít na jednoduché výpočty. Díky tomu nemusím mít řadu specializovaných programů, mám plnou kontrolu nad tím, co daný program dělá, programy se mnou komunikují v češtině, pokud mi něco nevyhovuje, není problém to opravit či předělat.
Recenze k programu je například zde. Stručný manuál je v angličtině, dá se jím prokousat.
A zde je pár příkladů:
1. Sportka
Program vygeneruje 6 náhodných čísel do sportky.Ovládání:
- Spuštění
- Tlačítka: OK - vygenerování nových čísel, A - setřídění vygenerovaných čísel, Cancel (B) - ukončení programu
# SPORTKA
new
5 dim a(12)
10 j=1
20 for i=1 to 11 step 2
30 c=rnd(50)
40 if c=0 then goto 10
50 for k=1 to i step 2
60 if c=a(k) then goto 10
70 next k
80 a(i) = c
90 s$(i-1) = 'Číslo '+str$(j)+' :'
100 j=j+1
110 next i
200 for i=1 to 11 step 2
210 s$(i) = str$(a(i))
220 next i
500 op 'dt','SPORTKA - náhodná čísla'
510 a = fn 30
520 if a=1 then goto 10
525 if a=2 then goto 1000
530 end
1000 for i=1 to 11 step 2
1010 idx=1
1020 for j=1 to 11 step 2
1030 if a(i)>a(j) then idx=idx+2
1040 next j
1050 s$(idx) = str$(a(i))
1060 next i
1070 goto 510
run
2. Body Mass Index
Pro zjištění, jak jsem na tom s mojí váhou.Ovládání:
- Spuštění
- Zadání váhy a výšky (na řádku 30 programu lze přednastavit svoji výšku, která se pak defaultně zobrazí na vstupu)
- Tlačítka: OK (A,B) - výpočet, Cancel - neprovedení výpočtu
- Případné nové zadání výšky a váhy
- Tlačítka (po prvním výpočtu): OK - nový výpočet, A - zobrazení doporučené váhy pro zadanou výšku, Cancel (B) - ukončení programu
# BODY MASS INDEX
new
10 s$(0)='Váha [kg] : '
20 s$(2)='Výška [cm] : '
30 s$(3)='180'
40 s$(4)=''
50 s$(5)=''
60 op 'dt','BODY MASS INDEX'
70 a=fn 30
80 s$(4)='BMI : '
90 m=val(s$(1))
100 n=(val(s$(3))/100)^2
110 bmi=m /n
120 s$(5)=str$(int(bmi*100)/100)
130 s$(8)='Vyzáblost : '
140 s$(9)='BMI do 15'
150 s$(10)='Hubenost : '
160 s$(11)='BMI 15 - 20'
170 s$(12)='Normál : '
180 s$(13)='BMI 20 - 25'
190 s$(14)='Nadváha : '
200 s$(15)='BMI 25 - 30'
210 s$(16)='Obezita : '
220 s$(17)='BMI nad 30'
500 b=fn 30
510 if b=2 then gosub 700
520 if b=1 then goto 90
600 end
700 op 'it','Doporučená váha pro '+s$(3)+' cm'
710 ? int(20*n),' - ', int(25*n),' kg'
720 b=1
730 return
run
3. Plat
Výpočet čistého platu na základě zadání hrubého platu a počtu vyživovaných dětí. Program nebere v úvahu žádné jiné odečitatelné položky kromě položek na dospělé osoby a děti.Ovládání:
- Spuštění
- Zadání hrubého platu a počtu dětí (lze přednastavit na řádcích 30 a 50). Hrubý plat lze zadat i jako matematický výraz (např.: 20000*1,5)
- Tlačítka: OK (A,B, Cancel) - provedení výpočtu
- Případné nové zadání hrubého platu a počtu dětí
- Tlačítka: OK - nový výpočet, A - zobrazení, kolik za mě ještě platí zaměstavatel (z této obrazovky se lze dostat jakýmkoli tlačítkem), Cancel (B) - ukončení programu
# PLAT
new
20 s$(0)='Hrubý : '
30 s$(1)='20000'
40 s$(2)='Dětí : '
50 s$(3)='1'
60 k_dosp=38040/12
70 k_dite=25560/12
80 k_15=109200/12
90 k_20=218400/12
100 k_25=331200/12
110 k_poj_ja=12.5/100
120 k_poj_zam=35/100
# *************
125 hruby=eval(s$(1))
130 op 'dt','PLAT'
140 b=fn 30
150 hruby=eval(s$(1))
160 deti=val(s$(3))
170 soc_ja=int(hruby*k_poj_ja)
180 soc_zam=int(hruby*k_poj_zam)
190 od_pol=k_dosp+(deti*k_dite)
200 dzakl=int(hruby-soc_ja)
210 zm=int(dzakl - od_pol)
220 zm=(int(zm/100)+1)*100
230 if zm <= k_15 then gosub 600
240 if zm > k_15 and zm <= k_20 then gosub 700
250 if zm > k_20 and zm <= k_25 then gosub 800
260 if zm > k_25 then gosub 900
265 s$(1)=str$(hruby)
270 s$(4)='Poj. 12,5% : '
280 s$(5)=str$(soc_ja)
290 s$(6)='Zákl. daně : '
300 s$(7)=str$(dzakl)
310 s$(8)='Odeč. pol. : '
320 s$(9)=str$(od_pol)
330 s$(10)='Zdan. mzda : '
340 s$(11)=str$(zm)
350 s$(12)='Daň : '
360 proc=int(dan/dzakl*1000)/10
370 s$(13)=str$(dan)+', '+str$(proc) + '% ZD'
380 s$(14)='Celk. státu : '
390 proc=int((soc_ja+dan)/hruby*100)
400 s$(15)=str$(soc_ja+dan) + ', ' + str$(proc) + '% hr.'
410 s$(16)='ČISTÝ : '
420 s$(17)=str$(hruby-soc_ja-dan)
425 op 'dt','PLAT'
430 a=fn 30
440 if a=2 then gosub 1000
450 if a=1 then goto 150
500 end
# *************
600 dan=zm*0.15
610 return
700 dan=k_15*0.15 + (zm-k_15)*0.20
710 return
800 dan=k_15*0.15 + (k_20-k_15)*0.20 + (zm-k_20)*0.25
810 return
900 d1=k_15*0.15 + (k_20-k_15)*0.20
910 d2=(k_25-k_20)*0.25 + (zm-k_25)*0.32
930 dan=d1+d2
940 return
1000 op 'dt','PLAT - zaměstnavatel'
1010 s$(4)='Zaměstnav. : '
1020 s$(5)=str$(soc_zam)
1030 s$(6)='Teor. hr. : '
1040 s$(7)=str$(soc_zam+hruby)
1050 s$(8)='Celk. státu : '
1060 s$(9)=str$(soc_zam+soc_ja+dan)
1070 s$(10)='% státu : '
1080 s$(11)=str$(int(val(s$(9))/val(s$(7))*100))
1090 for i=12 to 18
1100 s$(i)=''
1110 next i
1120 c=fn 30
1130 a=1
1140 return
run
4. Splátky
Výpočet měsíční splátky na základě znalosti celkové částky, roční úrokové míry, počtu let splácení a počtu splátek za rok.Ovládání:
- Spuštění
- Tlačítka: OK (Cancel,A,B) - výpočet
- Případné nové zadání vstupních údajů
- Tlačítka (po prvním výpočtu): OK - nový výpočet, Cancel (A,B) - ukončení programu
# SPLÁTKY
new
10 s$(0)='Půjčka : '
20 s$(2)='Roční úrok : '
30 s$(4)='Počet let : '
40 s$(6)='Spl. za rok : '
50 s$(1)='1000000'
60 s$(3)='5'
70 s$(5)='15'
80 s$(7)='12'
90 op 'dt','VÝPOČET SPLÁTEK'
100 a=fn 30
110 s$(10)='SPLÁTKA : '
120 s$(12)='ROČNĚ : '
130 s$(14)='CELKEM : '
140 s$(16)='NAVÍC : '
150 pujcka=val(s$(1))
160 urok=val(s$(3))/100
170 roku=val(s$(5))
180 zarok=val(s$(7))
190 pocsplatek=-(roku*zarok)
200 k1=urok/zarok
210 k2=1-(1+k1)^pocsplatek
220 splatka=pujcka*k1/k2
230 s$(11)=str$(int(splatka))
240 s$(13)=str$(int(splatka*zarok))
250 celkem=-splatka*pocsplatek
260 s$(15)=str$(int(celkem))
270 navic=celkem-pujcka
280 proc$=str$(int(navic/pujcka*100))+' %'
290 s$(17)= str$(int(navic))+', '+proc$
300 b=fn 30
310 if b=1 then goto 110
500 end
run
